dealloc和weak原理

weak原理

runtime维护sidetables哈希表，sidetables里含有64个sidetable，每个sidetable管理若干个对象，通过对象地址找到对应的weak表，weak表中存储着若干个weak指针，若一个对象被weak，如果没有对应的表则创建，若有了则追加到后面

sidetable

• sidetable主要管理weak指针和辅助引用计数，原理图
  

dealloc底层实现

根据 runtime源码可知，

1. 首先调用_objc_rootDealloc() -> rootDealloc()
2. isTaggedPointer是否是标记指针是直接return
3. 若是优化的isa、没有被弱引用、没有关联对象、没有自定义的C++析构函数、没有用到sideTable来做引用计数,直接将对象释放free
4. 第3部任何不满足则继续处理，objc_destructInstance内部函数会销毁C++析构函数以及移除关联对象的操作，SideTable中擦除该对象的引用计数，将指向该对象的弱引用指针置为nil
5. 第4部操作完，将对象释放free

dealloc底层源码

• runtime源码

• rootdealloc实现

  inline void
  objc_object::rootDealloc()
  {
      //判断对象是否采用了Tagged Pointer技术
      if (isTaggedPointer()) return;  // fixme necessary?
      //判断是否能够进行快速释放
      //这里使用了isa指针里的属性来进行判断.
      if (fastpath(isa.nonpointer  &&  //对象是否采用了优化的isa计数方式
                   !isa.weakly_referenced  &&  //对象没有被弱引用
                   !isa.has_assoc  &&  //对象没有关联对象
                   !isa.has_cxx_dtor  &&  //对象没有自定义的C++析构函数
                   !isa.has_sidetable_rc  //对象没有用到sideTable来做引用计数
                   ))
      {
          //如果以上判断都符合条件，就会调用C函数 free 将对象释放
          assert(!sidetable_present());
          free(this);
      } 
      else {
          //如果以上判断没有通过，做下一步处理
          object_dispose((id)this);
      }
  }

• objc_destructInstance内部函数会销毁C++析构函数以及移除关联对象的操作.

     id  object_dispose(id obj){
      if (!obj) return nil;
      
      objc_destructInstance(obj);    
      free(obj);
      
      return nil;
  }

• 如果该对象采用了优化过的isa引用计数，从SideTable引用计数表中清除该对象的引用计数

  objc_object::clearDeallocating_slow() {
     assert(isa.nonpointer  &&  (isa.weakly_referenced || isa.has_sidetable_rc));
     // 在全局的SideTables中，以this指针(要释放的对象)为key，找到对应的SideTable
     SideTable& table = SideTables()[this];
     table.lock();
     if (isa.weakly_referenced) {
         //要释放的对象被弱引用了，通过weak_clear_no_lock函数将指向该对象的弱引用指针置为nil
         weak_clear_no_lock(&table.weak_table, (id)this);
     }
     //使用了sideTable的辅助引用计数,直接在SideTable中擦除该对象的引用计数
     if (isa.has_sidetable_rc) {
         table.refcnts.erase(this);
     }
     table.unlock();
   }

• 从SideTable,将被弱引用对象的弱引用指针置为nil.

   void  weak_clear_no_lock(weak_table_t *weak_table, id referent_id)  {
    //获取被弱引用对象的地址
    objc_object *referent = (objc_object *)referent_id;
    // 根据对象地址找到被弱引用对象referent在weak_table中对应的weak_entry_t
    weak_entry_t *entry = weak_entry_for_referent(weak_table, referent); 
    if (entry == nil) {
        /// XXX shouldn't happen, but does with mismatched CF/objc
        //printf("XXX no entry for clear deallocating %p\n", referent);
        return;
    }
    // zero out references
    weak_referrer_t *referrers;
    size_t count;
    // 找出弱引用该对象的所有weak指针地址数组
    if (entry->out_of_line()) {
        referrers = entry->referrers;
        count = TABLE_SIZE(entry);
    } 
    else {
        referrers = entry->inline_referrers;
        count = WEAK_INLINE_COUNT;
    }
    // 遍历取出每个weak指针的地址
    for (size_t i = 0; i < count; ++i) {
        objc_object **referrer = referrers[i]; 
        if (referrer) {
            // 如果weak指针确实弱引用了对象 referent，则将weak指针设置为nil
            if (*referrer == referent) { 
                *referrer = nil;
            }
            // 如果所存储的weak指针没有弱引用对象 referent，这可能是由于runtime代码的逻辑错误引起的，报错
            else if (*referrer) { 
                _objc_inform("__weak variable at %p holds %p instead of %p. "
                             "This is probably incorrect use of "
                             "objc_storeWeak() and objc_loadWeak(). "
                             "Break on objc_weak_error to debug.\n", 
                             referrer, (void*)*referrer, (void*)referent);
                objc_weak_error();
            }
        }
    }
    weak_entry_remove(weak_table, entry);
  }